آموزش تابع Average در اکسل – به زبان ساده + مثال

یکی از عملیات‌های مختلفی که می‌شود روی اعداد در اکسل انجام داد، دریافت میانگین است. این عملیات نیز مانند جمع در اکسل، کاربرد بسیاری دارد و کاربران از آن استفاده‌های مختلفی می کنند. به همین دلیل نیز اکسل تابعی مخصوص برای انجام آن ارائه کرده است. به همین منظور، در این مقاله تابع «Average» در اکسل را بررسی خواهیم کرد. برای یادگیری سایر توابع اکسل و قابلیت‌های آن می‌توانید راهنمای «چگونه اکسل یاد بگیریم» را نیز مطالعه کنید.

تابع Average در اکسل

از تابع Average در اکسل برای محاسبه میانگین اعداد مشخص استفاده شده و سینتکس آن مانند فرمول زیر نوشته می‌شود‌:

1AVERAGE(number1, [number2], …)

در این فرمول، عبارات number1  و number2  نشان دهنده مقادیر عددی برای محاسبه میانگین هستند.

فیلم مجموعه آموزش اکسل – مقدماتی تا پیشرفته در فرادرس

کلیک کنید

می‌توانید آن‌ها را به شکل عدد یا مقادیر عددی، آرایه یا ارجاع به سلول و محدوده، در فرمول بیاورید. همچنین خوب است بدانید، نوشتن اولین آرگومان ضروری است و باقی آن‌ها اختیاری هستند و می‌توانید در یک فرمول، تا 255 آرگومان را وارد کنید.

6 نکته مهم درباره تابع Average در اکسل

استفاده از این تابع در اکسل بسیار ساده است اما نکاتی هستند که بهتر است پیش از استفاده، از آن‌ها آگاه باشید.

• توجه داشته باشید که سلول‌های حاوی مقادیر صفر، در میانگین محاسبه می‌شوند.
• سلول‌های خالی نادیده گرفته خواهند شد.
• همچنین سلول‌های حاوی مقادیر متنی یا منطقی مانند «True» و «False»‌ نیز محاسبه نمی‌شوند. اگر می‌خواهید مقادیر بولین یا نمایش متنی اعداد را در میانگین دخیل کنید باید از تابع AverageA کمک بگیرید.
• البته مقادیر بولینی که به طور مستقیم درون فرمول نوشته شده باشند، در میانگین محاسبه می‌شوند. مثلا نتیجه میانگین AVERAGE(TRUE, FALSE) ، می‌شود عدد 0.5 که درواقع میانگین «1» و «0» است.
• اگر آرگومان‌های مشخص شده، حاوی مقدار عددی معتبر نباشند، با خطای DIV/0 مواجه خواهید شد.
• آرگومان‌هایی که دارای مقادیر خطا هستند، باعث می‌شوند تابع Average نیز در خروجی خطا نشان دهد. برای ریفع این مشکل می‌توانید از روش‌های پنهان کردن خطاها در اکسل استفاده کنید.

لطفا هنگام کار با تابع Average در اکسل مد نظر داشته باشید که سلول‌های خالی و سلول‌های دارای مقدار صفر، به طور متفاوت مورد استفاده قرار می‌گیرند. یعنی عدد صفر در میانگین محاسبه می‌شود اما سلول‌های خالی نادیده گرفته می‌شوند. البته اگر گزینه «Show a zero in cells that have a zero value»‌ در سند شما تیک نخورده باشد، ممکن است شرایط کمی پیچیده شود. پس برای تغییر این حالت وارد مسیر Options > Advanced > Display options شوید و گزینه مورد نظر را تیک بزنید.

فرمول تابع Average در اکسل

برای ساخت یک فرمول میانگین‌گیری اساسی در اکسل کافی است مقادیر منبع را برای آن فراهم کنید که به شکل‌های مختلف قابل انجام است.

برای محاسبه میانگین چند عدد خاص باید آن‌ها را به طور مستقیم درون فرمول بنویسید. مثلا، فرمول میانگین‌گیری اعداد 1 ،2 ،3 و 4 به شکل زیر خواهد شد:

1=AVERAGE(1,2,3,4)

یا برای محاسبه میانگین کل یک ستون باید از روش های ارجاع دادن در اکسل استفاده کنید که فرمول آن شبیه به مثال زیر می‌شود:

1=AVERAGE(1:1)

برای میانگین‌گیری محدوده‌ای از سلول‌ها باید همان محدوده را درون فرمول بیاورید، مانند مثال زیر:

1=AVERAGE(A1:C20)

اگر می‌خواهید میانگین چند سلول غیرمجاور را حساب کنید، هر مرجع سلولی باید به طور مجزا و مانند فرمول زیر، ارائه شود:

1=AVERAGE(A1, C1, D1)

همچنین برای محاسبه میانگین چندین محدوده باید به هر کدام از آن‌ها به طور جداگانه ارجاع دهید که در نهایت به چیزی شبیه به مثال زیر می‌رسید:

1=AVERAGE(A1:A20, C1:D10)

در نهایت باید گفت هیچ چیزی مانع شما برای کنار هم قرار دادن مقادیر، سلول‌ها و ارجاعات محدوده‌ای درون یک فرمول نیست و می‌توانید مانند مثال زیر، از تمام آن‌ها در یک فرمول کمک بگیرید:

1=AVERAGE(B3:B5, D7:D9, E11, 100)

در مجموعه داده زیر نیز می‌بینید که نتیجه استفاده از تابع Average در اکسل به شکل‌های مختلف، چگونه بوده است.

نحوه استفاده از تابع Average در اکسل

به غیر از اعداد، تابع Average می‌تواند به راحتی میانگین مقادیر عددی دیگر مانند درصد و زمان را نیز پیدا کنید. در ادامه بیشتر درباره این مورد صحبت می‌کنیم.

فیلم آموزش محاسبات آماری در اکسل Excel در فرادرس

کلیک کنید

محاسبه میانگین درصد در اکسل

برای محاسبه میانگین درصد در اکسل کافی است از یک فرمول معمولی کمک بگیرید. نکته کلیدی اینجاست که باید قالب بندی سلول در اکسل را به درصد تغییر دهید. به عنوان نمونه برای محاسبه میانگین سلول‌های C2 تا C11 در این مثال باید از فرمول زیر کمک بگیرید:

1=AVERAGE(C3:C7)

دریافت میانگین زمان در اکسل

محاسبه واحدهای متفاوت زمانی به طور دستی می‌تواند بسیار سخت باشد. خوشبختانه تابع Average در اکسل به خوبی با زمان نیز هماهنگ است. اما برای نمایش درست میانگین زمان در اکسل، فراموش نکنید که قالب بندی سلول نتیجه را به تاریخ تغییر دهید.

در مثال زیر می‌بینید که به کمک فرمول مربوطه، میانگین زمان دویدن تمام بازیکنان را به دست آورده‌ایم:

1=AVERAGE(B2:B6)

میانگین در اکسل بدون محاسبه صفرها

همان‌طور که گفتیم، تابع Average اکسل، سلول‌های خالی یا محتوی مقادیر متنی و منطقی را نادیده می‌گیرد اما صفرها را حساب می‌کند. در تصویر زیر نیز می‌بینید که میانگین موجود در سلول‌های E4 ،E5 و E6 دقیقا مانند مقدار سلول E3 هستند.

سلول خالی و حاوی مقادیر نامعتبر موجود در ستون C نادیده گرفته شده و تنها اعداد موجود در ستون‌های B و D محاسبه شده‌اند. با این حال مقدار صفر موجود در سلول C7، در میانگین سلول ‌E7 مورد محاسبه قرار گرفته است، چون به عنوان مقداری مورد قبول شناخته می‌شود.

برای عدم محاسبه صفرها می‌توانید از توابع AverageIF یا AverageIFS کمک بگیرید، مانند مثالی که در ادامه می‌بینیم:

1=AVERAGEIF(B3:D3, "<>0")

میانگین N مقدار بیشتر یا کمتر

برای دریافت 3 ،5 ،10 یا N بالاترین مقدار در یک محدوده می‌توانید تابع Average را در ترکیب با تابع Large در اکسل به کار ببرید که شبیه به فرمول زیر خواهد شد:

1AVERAGE(LARGE(range, {1,2,3, …, n}))

به عنوان مثال برای به‌دست آوردن میانگین 3 مورد از بزرگ‌ترین اعداد در محدوده B3:B11، از فرمول زیر کمک می‌گیریم:

1=AVERAGE(LARGE(B3:B11,{1,2,3}))

یا محاسبه میانگین 3 مورد از کمترین اعداد در این محدوده، فرمول زیر را می‌نویسیم:

1=AVERAGE(SMALL (B3:B11, {1,2,3}))

نتایج این دو فرمول را می‌توانید در تصویر زیر ببینید:‌

فرمول چگونه کار می‌کند

به طور معمول، تابع Large، برای به‌دست آوردن «Nامین» مقدار بزرگ در یک آرایه به کار می‌رود. برای محاسبه N مقدار بالا، از یک آرایه ثابت مانند {1,2,3} به جای آرگومان دوم استفاده می‌شود. در این مثال، تابع Large، سه عدد بزرگ‌تر محدوده را که اعداد 20 ،18 و 19 هستند، به‌دست می‌آورد. سپس تابع Average وارد کار شده و میانگین آن‌ها را حساب می‌کند. ترکیب دو تابع Small و Average نیز دقیقا به همین شکل پیش می‌رود.

استفاده از تابع Average If در اکسل

برای محاسبه میانگین با شرایط خاص باید از توابع AverageI fs یا Average If کمک بگیرید که در ادامه بیشتر درباره آن‌ها صحبت می‌کنیم. در واقع می‌خواهیم تابع IF در اکسل را با تابع Average ترکیب کنیم.

• مطالب بیشتر برای مطالعه:
  • فرق فرمول و تابع در اکسل — به زبان ساده + فیلم آموزشی رایگان
  • تابع SUMIF در اکسل — آموزش با مثال‌های کاربردی
  • نوشتن فرمول جمع در اکسل — به زبان ساده + مثال و فیلم آموزشی رایگان
  • تابع Countif در اکسل — به زبان ساده و با مثال + فیلم آموزشی رایگان
  • فرمول چند شرطی در اکسل — به زبان ساده

تابع AverageIf با یک شرط

برای محاسبه میانگین در شرایطی که یک معیار دارید باید تابع را به شکل فرمول زیر بنویسید:

1AVERAGE(IF(criteria_range=criteria, average_range))

در اکسل 2019، این فرمول فقط به عنوان یک فرمول آرایه کار می‌کند، این یعنی باید برای اجرای درست آن، پس از نوشتن فرمول، دکمه‌های «Ctrl + Shift + Enter» را روی کیبورد فشار دهید. البته در اکسل 365 و نسخه 2021، فرمول مانند هر تابع معمولی دیگری کار می‌کند و نیازی به فشردن هیچ دکمه‌ای نیست.

قصد داریم در مثال زیر، میانگین نمرات «ریاضی» را محاسبه کنیم و برای این کار کافی است کلمه «ریاضی» را به عنوان شرط بنویسیم تا فرمول چیزی شبیه به نمونه زیر شود:‌

1=AVERAGE(IF(C3:C11="ریاضی", B3:B11))

همچنین می‌توانیم شرط را در سلول مجزایی بنویسیم و در فرمول به آن ارجاع دهیم. در این مثال عبارت شرط را در سلول «F3» نوشته‌ایم.

1=AVERAGE(IF(C3:C11=F3, B3:B11))))

نحوه کارکرد فرمول

آزمون منطقی تابع IF، هر موضوع را در محدوده C2:C10، با هدف موجود در سلول F3 مقایسه می‌کند. نتیجه این مقایسه، آرایه‌ای شامل عبارت True یا False است که در آن، هر عبارت True، معنی مطابقت دارد. آرایه آزمون این مثال شبیه به نمونه زیر خواهد شد:

1{FALSE;FALSE;FALSE;TRUE;TRUE;FALSE;FALSE;TRUE;FALSE}

به جای آرگومان «value_ if_true»، محدوده B2:B10 را قرار داده‌ایم تا اگر خروجی آزمون منطقی، True بود، نمره متناظر با آن در خروجی قرار بگیرد. همچنین از آن‌جایی که آرگومان «value_ if_false» حذف شده است، اگر شرط براورده نباشد عبارت False نشان داده خواهد شد و نتیجه شبیه به آرایه زیر می‌شود:

1{FALSE;FALSE;FALSE;19;15;FALSE;FALSE;19;FALSE}

سپس این آرایه تحویل تابع Average داده می‌شود، که در نهایت با نادیده گرفتن عبارات ‌False، میانگین سه عدد موجود را حساب می‌کند.

استفاده از تابع AverageIf با چند شرط

فرمول تابع AverageIf با وجود چند شرط به شکل فرمول زیر نوشته می‌شود:

1AVERAGE(IF((criteria_range1=criteria1) * (criteria_range2=criteria2), average_range))

مثلا برای محاسبه میانگین نمرات «ریاضی» در «کلاس اول» باید از فرمول زیر استفاده شود:

1=AVERAGE(IF((C2:C10="ریاضی") * (D2:D10="اول"), B2:B10))

این فرمول همچنین می‌تواند مانند مثال زیر، با ارجاعات سلولی کار کند:

1=AVERAGE(IF((C2:C10=F2) * (D2:D10=F3), B2:B10))

فراموش نکنید که در اکسل 2019 و نسخه‌های پایین‌تر باید برای کارکرد درست این فرمول، دکمه‌های Ctrl+Shift+Enter را فشار دهید.

البته در اکسل 365 و نسخه 2021 نیازی به این کار نیست.

فرمول بالا را همچنین می‌توانیم با ترکیب دو تابع IF مانند مثال زیر نیز بنویسیم و نتیجه مشابه را بگیریم:

1=AVERAGE(IF(C2:C10=F2, IF(D2:D10=F3, B2:B10)))

انتخاب یکی از این فرمول‌ها به خودتان بستگی دارد، در ادامه نتیجه این ترکیب را می‌بینیم.

فرمول چگونه کار می‌کند؟

در این آزمون منطقی IF، دو مقایسه انجام می‌شوند. ابتدا فهرست موضوعات را در محدوده C2:C10 بر اساس مقدار موجود در سلول F2، مقایسه کرده و سپس کلاس‌های موجود در ستون D2:D10 را نسبت به مقدار سلول F3 ارزیابی می‌کنید. به این ترتیب، دو آرایه متشکل از عبارات False و True خواهید داشت و عملیات ضرب در این میان مانند عملگر «And» عمل می‌کند.

فیلم آموزش اکسل – محاسبات ریاضی و ماتریسی با Microsoft Excel 2016 در فرادرس

کلیک کنید

در هر عملیات حسابی، عبارت True برابر مقدار «1» و False برابر «0» است و می‌دانیم ضرب در صفر، همیشه صفر خواهد شد. پس آرایه خروجی تنها در صورتی شامل عدد «1» خواهد بود که هر دو شرط، True‌ باشند یا براورده شوند. این آرایه در آزمون منطقی IF ارزیابی شده است تا نمرات منطبق با مقادیر «1» را در خروجی نشان دهد که شبیه به نمونه زیر است:

1{FALSE;FALSE;FALSE;19;17;FALSE;FALSE;FALSE;FALSE}

سپس این آرایه نهایی به تابع Average برمی‌گردد تا میانگین اعداد به‌دست آمده، توسط آن محاسبه شود.

چگونه میانگین تابع Average در اکسل را رند کنیم؟

اگر قصد دارید تنها اعداد میانگینی که نمایش داده می‌شوند را رند کرده و کاری با مقادیر زیرین ندارید، بهتر است از دستور «Decrease Decimal» یا گزینه قالب بندی سلول در اکسل کمک بگیرید.

رند کردن مقدار میانگین با کمک گزینه Format Cells

برای گرد کردن اعداد اعشاری در اکسل، کافی است روی آن راست‌کلیک کرده و گزینه «Format cells»‌ را انتخاب کنید. همچنین می‌توانید پس از انتخاب سلول موردنظر، دکمه‌های «Ctrl+1» را نیز به طور همزمان فشار دهید. در پنجره جدید به بخش «Number» بروید و تعداد اعشار مورد نظر را در کادر «Decimal places» بنویسید.

توجه داشته باشید که این روش، تنها مقدار نمایشی را عوض می‌کند و اگر در فرمول‌های دیگر به این سلول ارجاع دهید، مقدار رند نشده آن محاسبه خواهد شد.

استفاده از گزینه Decrease Decimal برای رند کردن میانگین

روش بعدی برای رند کردن مقدار نمایشی میانگین در سلول همچنین می‌توانید سلول موردنظر را برگزینید و گزینه Decrease Decimal را در زبانه Home بزنید.

این روش نیز تنها مقدار نمایشی در همین سلول را عوض می‌کند.

رند کردن مقدار محاسبه شده میانگین

برای گرد کردن مقدار محاسبه شده سلول، بهتر است تابع Average را همراه با یکی از توابع رند کردن در اکسل استفاده کنید. برای پیروی از قوانین کلی گرد کردن، Average را در کنار تابع Round بیاورید. در آرگومان دوم (Num_digits)، تعداد ارقام موردنظر برای رند کردن میانگین را بنویسید.

مثلا برای گرد کردن یک میانگین به نزدیک‌ترین مقدار عددی، از فرمول زیر کمک بگیرید:

1=ROUND(AVERAGE(B3:B11), 0)

همچنین برای اضافه کردن یک رقم اعشار، مانند مثال زیر، عدد «1» را به جای آرگومان Num_digits بنویسید:

1=ROUND(AVERAGE(B3:B11), 1)

به همین شکل برای افزودن دو رقم اعشار کافی است مانند نمونه زیر، به جای این آرگومان، عدد «2» را قرار دهید:

1=ROUND(AVERAGE(B3:B11), 2)

استفاده از تابع RoundUp مانند مثال زیر، برای رند کردن رو به بالا به کار می‌رود:

1=ROUNDUP(AVERAGE(B3:B11), 1)

برای رند کردن به سمت پایین نیز مانند نمونه بعدی، از تابع RoundDown کمک بگیرید:

1=ROUNDDOWN(AVERAGE(B3:B11), 1)

نتایج این توابع را در تصویری که در ادامه می‌آید می‌توانید ببینید.

چگونه خطای Div/0 را در اکسل برطرف کنیم؟

اگر محدوده موردنظر برای محاسبه میانگین در اکسل، هیچ مقدار عددی‌ای نداشته باشد، تابع Average، خطای عدم امکان تقسیم بر صفر یا Div/0 را نشان می‌دهد. برای حل این مشکل می‌توانید به کمک تابع Count در اکسل، مجموع مقادیر عددی موجود را به‌دست آورید و اگر نتیجه بیشتر از «0»‌ بود، میانگین را حساب کنید، در غیر این‌صورت به شکلی تنظیم کنید که رشته خالی نشان داده شود.

فرمول مناسب برای انجام این کار مانند نمونه زیر نوشته می‌شود:

1IF(COUNT(range)>0, AVERAGE(range), "")

مثلا برای پرهیز از بروز خطای Div/0، در مجموعه داده این مثال، از فرمول زیر کمک می‌گیریم:

1=IF(COUNT(B6:B16)>0, AVERAGE(B6:B16), "")

تابع Average در اکسل و نادیده گرفتن خطاها

اگر برای محاسبه میانگین روی هر سلولی که خطا دارد، تلاش کرده باشید، نتیجه نیز خطا خواهد بود. برای رهایی از این مشکل، می‌توانید روش‌های بعدی را مورد استفاده قرار دهید.

تابع Average و IFerror

می‌توانید قبل از شروع به کار با تابع Average در اکسل، به کمک تابع IfError که فرمول آن به شکل زیر نوشته می‌شود، از شر خطاها خلاص شوید:

1AVERAGE(IFERROR(range,""))

توجه داشته باشید که باید در تمام نسخه‌ها به غیر از اکسل 365 و 2021 که آرایه‌ها به طور داخلی مدیریت می‌شوند، برای کارکرد درست این تابع، دکمه‌های Ctrl+Shift+Enter را روی کیبورد فشار دهید.

مثلا برای مجموعه داده نمونه از فرمول زیر استفاده کرده‌ایم تا خطایی رخ ندهد:

1=AVERAGE(IFERROR(B6:B11,""))

تابع AGGREGATE

یک روش ساده دیگر برای نادیده گرفتن خطاها هنگام میانگین‌گیری، استفاده از تابع «AGGREGATE» است. برای تنظیم تابع AGGREGATE به این منظور، باید آرگومان «function_num» را روی «1» (تابع Average) و آرگومان «options» را روی مقدار «6» (نادیده گرفتن مقادیر خطا) قرار دهید. در نهایت به چیزی مانند فرمول زیر می‌رسید:

1=AGGREGATE(1,6,B6:B11)

همان‌طور که در تصویر زیر می‌بینید، هر دو تابع به درستی کار کرده‌اند.

چرا تابع Average کار نمی‌کند؟

در ادامه نکاتی را می‌خوانیم که در مواقع عدم کارکرد درست تابع Average در اکسل، کمک کننده هستند.

مشکل قالب بندی اعداد به شکل متن در اکسل را چگونه درست کنیم؟

همان‌طور که قبل‌تر نیز دیدیم، اگر محدوده موردنظر برای محاسبه میانگین دارای هیچ مقدار عددی‌ای نباشد، با خطای Div/0 مواجه می‌شوید. این اتفاق معمولا زمانی رخ می‌دهد که اعداد موجود در سلول‌ها به عنوان متن قالب بندی شده باشند. برای رفع این مشکل کافی است متن را به عدد تبدیل کنید. ساده‌ترین راه، راست‌کلیک کردن روی سلول‌های مربوطه، زدن گزینه Format Cells و سپس انتخاب گزینه Number در پنجره جدید است.

وجود مقادیر خطا در سلول‌های ارجاعی

اگر در فرمول تابع Average در اکسل به سلولی حاوی خطا ارجاع داده شده باشد، در نتیجه میانگین با خطا مواجه خواهید شد. برای رفع این مشکل می‌توانید تابع Average را در ترکیب با تابع IfError، یا Aggeregate، به کار ببرید که در مراحل قبلی روش کار با آن‌ها را توضیح دادیم. همچنین می‌توانید در صورت امکان، خطای موجود در سلول ارجاعی را با متنی عوض کنید تا نادیده گرفته شود.

نمایش فرمول Average در سلول به جای نتیجه

اگر سلول نتیجه شما به جای پاسخ، فرمول را نشان می‌دهد، به احتمال زیاد حالت نمایش فرمول در صفحه کاری شما فعال باشد. دلیل دیگر این است که شاید فرمول به عنوان متن نوشته شده است. این اتفاق ممکن است با گذاشتن فاصله یا علامت اضافه قبل از عملگر مساوی، اتفاق بیفتد. در ادامه روش‌های مختلف حل این مسئله را می‌بینیم.

چگونه مشکل فعال بودن نمایش فرمول را در اکسل رفع کنیم؟

رایج‌ترین علت اینکه فرمول اکسل به درستی محاسبه نمی‌کند، فعال بودن حالت نمایش فرمول است. برای نمایش نتیجه و پاسخ، باید این ویژگی را خاموش کنید. به این منظور دکمه‌های Ctrl + ` را بزنید یا در گروه «Formula Auditing » در زبانه «Formulas» اکسل، روی گزینه «Show Formulas»‌ کلیک کنید.

چگونه مشکل نوشته شدن فرمول به عنوان متن را در اکسل رفع کنیم؟

یکی دیگر از دلایل عدم کارکرد صحیح فرمول در اکسل، قالب بندی شدن سلول مربوطه برای متن است. برای بررسی این مورد، سلول فرمول را انتخاب کرده و در زبانه «Home» و گروه «Number»، کادر «Number Format» را نگاهی بیندازید. اگر عبارت «Text» را دیدید، روی علامت فلش کنار آن کلیک کرده و گزینه «General»‌ را انتخاب کنید. سپس وقتی داخل سلول بروید و دکمه F2 و بعد Enter را فشار دهید.

رفع مشکل وجود فاصله یا علامت اضافه در فرمول

اگر قبل از نوشتن «عملگر مساوی» (=) در فرمول خود، به طور اتفاقی فاصله یا علامت دیگری را نوشته باشید نیز ممکن است فرمول به درستی کار نکند. درواقع اکسل این سلول را به عنوان متن در نظر می‌گیرد. برای رفع این مشکل کافی است مجددا فرمول را بررسی کرده و هر علامت اضافه‌ای را قبل از عملگر مساوی پاک کنید.

سخن پایانی

در این مقاله تمام روش‌های استفاده از تابع Average در اکسل را بررسی کردیم. ابتدا مثال‌هایی از ساده‌ترین شکل فرمول تابع دیدیم. سپس نحوه کارکرد آن در شرایط مختلف همراه با معیارهای متفاوت را دیدیم. تلاش کردیم با ارائه مثال‌های مختلف، درک مفاهیم مرتبط با این تابع را ساده‌تر کنیم.

در ادامه پس از بررسی ترکیب تابع Average با سایر توابع اکسل برای رسیدن به نتایج موثرتر و بهتر، به سراغ خطاها رفتیم. دیدیم که چه خطاهایی در چه شرایطی بروز می‌کنند و سپس راه‌حل پرهیز و رفع هریک را نیز بررسی کردیم تا در صورت مشاهده هر کدام بتوانید به راحتی از آن‌ها رد شوید.